/*-------------------------------------------------*/
/* rom.x
/* 秋月H8-3694用リンカスクリプト
/* @since 9July2006 fenrir
/*-------------------------------------------------*/
OUTPUT_FORMAT("elf32-h8300")
OUTPUT_ARCH(h8300:h8300h)
ENTRY("_start")

/*----              メモリマップ              ----*/
MEMORY
{
    vectors(r) : o = 0x0000, l = 0x34
    rom(r)     : o = 0x0034, l = 32k - 0x34
    ram(rwx)   : o = 0xf780, l = 2k
    stack(rwx) : o = 0xff7c, l = 0x0004
}

/*----            各セクション定義            ----*/
SECTIONS
{

  /*リセットベクタと割り込みベクタ等の設定*/
  .vectors : {
    
	SHORT(ABSOLUTE(_start))                                                /*  0 リセット */
	SHORT(ABSOLUTE(_start))                                                /*  1 システム予約1 */
	SHORT(ABSOLUTE(_start))                                                /*  2 システム予約2 */
	SHORT(ABSOLUTE(_start))                                                /*  3 システム予約3 */
	SHORT(ABSOLUTE(_start))                                                /*  4 システム予約4 */
	SHORT(ABSOLUTE(_start))                                                /*  5 システム予約5 */
	SHORT(ABSOLUTE(_start))                                                /*  6 システム予約6 */
	SHORT(DEFINED(_int_nmi) ? ABSOLUTE(_int_nmi) : ABSOLUTE(_start))       /*  7 NMI(外部割込み) */
	SHORT(DEFINED(_int_trap0) ? ABSOLUTE(_int_trap0) : ABSOLUTE(_start))   /*  8 TRAPA#1 */
	SHORT(DEFINED(_int_trap1) ? ABSOLUTE(_int_trap1) : ABSOLUTE(_start))   /*  9 TRAPA#2 */
	SHORT(DEFINED(_int_trap2) ? ABSOLUTE(_int_trap2) : ABSOLUTE(_start))   /* 10 TRAPA#3 */
	SHORT(DEFINED(_int_trap3) ? ABSOLUTE(_int_trap3) : ABSOLUTE(_start))   /* 11 TRAPA#4 */
	SHORT(ABSOLUTE(_start))                                                /* 12 ブレーク条件成立 */
	SHORT(ABSOLUTE(_start))                                                /* 13 スリープ命令の実行による直接遷移 */
	SHORT(DEFINED(_int_irq0) ? ABSOLUTE(_int_irq0) : ABSOLUTE(_start))     /* 14 IRQ0 */
	SHORT(DEFINED(_int_irq1) ? ABSOLUTE(_int_irq1) : ABSOLUTE(_start))     /* 15 IRQ1 */
	SHORT(DEFINED(_int_irq2) ? ABSOLUTE(_int_irq2) : ABSOLUTE(_start))     /* 16 IRQ2 */
	SHORT(DEFINED(_int_irq3) ? ABSOLUTE(_int_irq3) : ABSOLUTE(_start))     /* 17 IRQ3 */
	SHORT(DEFINED(_int_wkp) ? ABSOLUTE(_int_wkp) : ABSOLUTE(_start))       /* 18 WKP */
	SHORT(DEFINED(_int_timera) ? ABSOLUTE(_int_timera) : ABSOLUTE(_start)) /* 19 タイマA */
	SHORT(ABSOLUTE(_start))                                                /* 20 システム予約7 */
	SHORT(DEFINED(_int_timerw) ? ABSOLUTE(_int_timerw) : ABSOLUTE(_start)) /* 21 タイマW */
	SHORT(DEFINED(_int_timerv) ? ABSOLUTE(_int_timerv) : ABSOLUTE(_start)) /* 22 タイマV */
	SHORT(DEFINED(_int_sci3) ? ABSOLUTE(_int_sci3) : ABSOLUTE(_start))     /* 23 SCI3 */
	SHORT(DEFINED(_int_iic2) ? ABSOLUTE(_int_iic2) : ABSOLUTE(_start))     /* 24 IIC2 */
	SHORT(DEFINED(_int_ad) ? ABSOLUTE(_int_ad) : ABSOLUTE(_start))         /* 25 A/D変換終了 */
	
  } > vectors
    
  /* プログラム領域＆参照のみのデータ領域 */
  .text : {
  	_text_begin = . ;
    *(.text)    /* プログラム領域 */
    *(.rodata)  /* コンスタント領域(read only) */
    *(.rodata.*)
    *(.gnu.linkonce.r.*)
    *(.gnu.linkonce.t.*)
    _text_end = . ;
  } > rom
  
  .tors : {
    _ctors_begin = . ;
    *(.ctors)
    _ctors_end = . ;
    _dtors_begin = . ;
    *(.dtors)
    _dtors_end = . ;
  } > rom
  
  /* 初期値を持つグローバル変数，スタティック変数領域 */
  .data : AT(ADDR(.tors) + SIZEOF(.tors)){
      _data_begin = . ;
      *(.strings) /* 文字列 */
      *(.data)
      *(.tiny)
      _data_end = . ;
  } > ram
  
  /* 初期値を持たないグローバル変数，スタティック変数領域 */
  .bss : {
    _bss_begin = . ;
    *(.bss)
    *(COMMON)
    _bss_end = . ;
    _end = . ;
  } > ram

  /* スタック領域 */
  .stack : {
    _initial_stack_point = . +4 ;
    _stack = . ;
    *(.stack)
  } > stack
  
  .eight : {
    *(.eight)
  } > ram
  
  /* デバックセクション */
  /* Stabs */
  .stab          0 (NOLOAD) : { *(.stab) }
  .stabstr       0 (NOLOAD) : { *(.stabstr) }
  .stab.excl     0 (NOLOAD) : { *(.stab.excl) }
  .stab.exclstr  0 (NOLOAD) : { *(.stab.exclstr) }
  .stab.index    0 (NOLOAD) : { *(.stab.index) }
  .stab.indexstr 0 (NOLOAD) : { *(.stab.indexstr) }
  .comment       0 (NOLOAD) : { *(.comment) }
  /* DWARF 1 */
  .debug          0 (NOLOAD) : { *(.debug) }
  .line           0 (NOLOAD) : { *(.line) }
  /* GNU DWARF 1 拡張 */
  .debug_srcinfo  0 (NOLOAD) : { *(.debug_srcinfo) }
  .debug_sfnames  0 (NOLOAD) : { *(.debug_sfnames) }
  /* DWARF 1.1 & DWARF 2 */
  .debug_aranges  0 (NOLOAD) : { *(.debug_aranges) }
  .debug_pubnames 0 (NOLOAD) : { *(.debug_pubnames) }
  /* DWARF 2 */
  .debug_info     0 (NOLOAD) : { *(.debug_info .gnu.linkonce.wi.*) }
  .debug_abbrev   0 (NOLOAD) : { *(.debug_abbrev) }
  .debug_line     0 (NOLOAD) : { *(.debug_line) }
  .debug_frame    0 (NOLOAD) : { *(.debug_frame) }
  .debug_str      0 (NOLOAD) : { *(.debug_str) }
  .debug_loc      0 (NOLOAD) : { *(.debug_loc) }
}